ASAHIKAWA

Flyby the city of Asahikawa in 64 bytes.

Is that even possible ?

There had been some great 64 bytes intro for DOS, but no voxel landscape so far. I wondered whether it was possible to fit this effect in 64 bytes for almost a year before sitting down and doing it. Turned out to be perfect time as Asahikawa beat another talented coder by a few hours and became the first 64 bytes intro to feature a voxel effect.

Source code

;
;     A s a h i k a w a
;
;    64b city  landscape
;
;    Mathieu 'p01' Henri
;    http://www.p01.org/
;
;    january  21st, 2007
;

org 100h

mov al,13h
int 10h
mov   bh,0a0h
mov   es,bx
main:
  mov    ax,di
  cdq
  mov    bx,320
  div    bx        ; ax = y, dx = x

  sub    dx,160
  mov    bx,dx     ; bx = x-160

  inc    ax        ;
  xchg    cx,ax    ; cx = y+1

  mov    ah,32
  cwd
  div    cx        ; ax = perspScale = ~y projected

  imul    bx,ax    ; bx = (x-160)*perspScale = ~x projected

  add    ax,si     ; frame offset
  and    al,240    ; al = v*16
  shr    bx,12     ; bx = u


  xlat             ; buildings 'LUT'
  xor    ax,bp     ; al = ~height of the building

  push  di
loop_y:
    or  al,16
    stosb
    sub  di,321
    inc  ax
    and  al,15
  jnz  loop_y

  pop  di
  inc  di

  jnz  main
  inc  si          ; next frame
  jnz  main

db  03h            ; <3

Feedback

Obviously Asahikawa is available on Pouet

Other recent experiments

There are many experiments and projects like ASAHIKAWA to discover other here.

• FRONTFEST MOSCOW It was an honour to be invited to Fronfest Moscow 2017 with the little family to give my first workshop; implementing a Twin-stick shooter using ES6 and Canvas, and to continue my CODE🎙ART series of talks + live coding aiming to inspire new web developer artists. on November 18th, 2017
• VOLTRA VOLTRA: Grinding the Universe, a gritty JavaScript demo, winner of the 1024 bytes demo competition at the Assembly 2017. on August 6th, 2017
• BREATHING EARTH Another take on Nadieh Bremer mesmerizing Breathing Earth visualisation, running at 60fps on a 2D Canvas without libraries or frameworks. on June 26th, 2017
• MICRO NOVA Quite possibly the smallest WebGL demo effect. Micro Nova clocks under 512bytes and shows supernova-like blasting colors. on May 30th, 2012
• PNEBULA Almost the first 256b intro using Canvas ever :p on September 30th, 2008
• OOMA 2 Rotozoom with tilt and experimental music in a valid 480bytes Atari bootsector. on May 13th, 2007
• STARFIELD A simple 3D starfield with title and fog in 256 bytes of Javascript on February 25th, 2007
• MANDELBROT ROTOZOOM Many people did fractals renderers in Javasript in 256 bytes, but no one ever made one that zooms and rotate... until today. on September 1st, 2006

Let's talk

Don't be shy; get in touch by mail, twitter, github, linkedin or pouet if you have any questions, feedback, speaking, workshop or performance opportunity.